initial import

gnome-themes-extra/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=gnome-themes-extra
+pkgver=3.28
+pkgrel=1
+pkgdesc="Extra Themes for GTK+ based Applications"
+url='https://gitlab.gnome.org/GNOME/gnome-themes-extra'
+arch=('i686' 'x86_64')
+license=('LGPL-2.1')
+depends=('cantarell-fonts')
+makedepends=('intltool' 'gettext-tiny' 'gtk2' 'gtk')
+provides=("gnome-themes-standard=$pkgver")
+source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/g/gnome-themes-extra/gnome-themes-extra_${pkgver}.orig.tar.xz")
+sha512sums=('bccc446e86b12476b86a0fe2e3354500c8fb3eef62a85c3823d69aaa259e032e1f94e7993bf633397b669c425ef42635b0cf17b376f0b7cf1869bb1d7160ede0')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  intltoolize
+  autoreconf -fvi
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure \
+    --prefix=/usr
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
+}