initial import

glib-networking/PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=glib-networking
+pkgver=2.66.0
+pkgrel=1
+pkgdesc="Network extensions for GLib"
+url="https://gitlab.gnome.org/GNOME/glib-networking"
+arch=(i686 x86_64)
+license=(custom:LGPL-2)
+depends=(glib2 libproxy gnutls gsettings-desktop-schemas)
+makedepends=(meson)
+checkdepends=(ca-certificates)
+source=(https://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz
+        remove-systemd-support.patch)
+sha512sums=('697798864746b40542873257a789290cacee425467e32c0eb096c87e124b37510753a990ef5d350f1db85c24da88e448bca9d8d8b4308123a74feac299176de5'
+            '449dca3f9b8c6fc117b5df7c4afbca889b5dfec1fd6c247c18eea7472b6cc9db60841c09b68c9e49258b6940edad262e015f47144496b59080b97e2025bbd22c')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -p1 -i ../remove-systemd-support.patch
+}
+
+build() {
+  hyperbola-meson $pkgname-$pkgver build -D openssl=disabled
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+  for i in COPYING LICENSE_EXCEPTION; do
+    install -Dm644 $pkgname-$pkgver/$i $pkgdir/usr/share/licenses/$pkgname/$i
+  done
+}
+
+# vim:set ts=2 sw=2 et:

glib-networking/remove-systemd-support.patch

@@ -0,0 +1,29 @@
+diff --git a/proxy/libproxy/meson.build b/proxy/libproxy/meson.build
+index e459bc1..6c3a608 100644
+--- a/proxy/libproxy/meson.build
++++ b/proxy/libproxy/meson.build
+@@ -3,24 +3,6 @@ service_conf.set('libexecdir', libexecdir)
+ 
+ service = 'org.gtk.GLib.PACRunner.service'
+ 
+-configure_file(
+-  input: service + '.in',
+-  output: service,
+-  install: true,
+-  install_dir: join_paths(datadir, 'dbus-1', 'services'),
+-  configuration: service_conf
+-)
+-
+-service = 'glib-pacrunner.service'
+-
+-configure_file(
+-  input: service + '.in',
+-  output: service,
+-  install: true,
+-  install_dir: join_paths('lib', 'systemd', 'user'),
+-  configuration: service_conf
+-)
+-
+ sources = files(
+   'glibproxyresolver.c',
+   'libproxy-module.c'