initial import

gftp/PKGBUILD

@@ -0,0 +1,35 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=gftp
+pkgver=2.9.1b
+pkgrel=1
+pkgdesc="A multithreaded FTP-client for X Windows"
+arch=('i686' 'x86_64')
+url='https://github.com/masneyb/gftp'
+license=('Expat')
+depends=('gtk2' 'libressl' 'readline')
+makedepends=('intltool' 'gettext-tiny')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/masneyb/gftp/archive/refs/tags/$pkgver.tar.gz"
+        "libre.patch")
+sha512sums=('82db633a169c06ab419ea9cb45feac9f81319af3b619797021da959cc7ae6a5196b8d603e6354539ee4525d834798c1a75e3ae2d26d79148a46e06496bb0e4e2'
+            '605c925cfe1e39c6b1b681cb3247dd43359fec43ff5aeedbb3ca30e21f8de926aa6e5b9effefe99f75606f173cef28f4dbbdb8cf70be2b41259d5d84b915c118')
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver"
+  patch -Np1 -i ${srcdir}/libre.patch
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+  ./autogen.sh
+  ./configure \
+    --prefix=/usr \
+    --mandir=/usr/share/man
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
+}