initial import

gegl/PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=gegl
+pkgver=0.4.30
+pkgrel=4
+pkgdesc="Graph based image processing framework"
+arch=('i686' 'x86_64')
+url='https://www.gegl.org/'
+license=('GPL-3' 'LGPL-3') # gegl-common-gpl3.so (gegl plugin operation) and software/libraries (LGPL-3)
+depends=('babl' 'ffmpeg' 'gdk-pixbuf2' 'jasper' 'json-glib' 'libraw' 'librsvg-legacy' 'libspiro'
+         'luajit' 'pango' 'poly2tri-c' 'poppler-glib' 'sdl2')
+makedepends=('gobject-introspection' 'libnsgif' 'meson' 'python-pygobject' 'vala') # libnsgif required, but build with libnsgif static submodule
+optdepends=('gobject-introspection: gir bindings'
+            'vala: vala bindings')
+source=("https://download.gimp.org/pub/$pkgname/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz")
+sha512sums=('73db2d18260ba061fbbc2adb3256ea9d5b822b57f5654cc3aefb59e7afeeb2e4f0fd7e95ac14603c0a549935df04d5744001089efb378511c914c68664dbd378')
+
+build() {
+  # required by seamless-clone/libgegl-sc-0.4.so build
+  export LDFLAGS+=" -lm"
+
+  # docs and graphviz disabled; requires gtkdoc and others dependencies
+  # umfpack is disabled; webp disabled out of security-reasoning;
+  # due the suiteparse package contains problematic licenses and dependencies
+  # workshop disabled (including: lensfun, maxflow and v4l-utils); contains experimental features
+  # libv4l (v4l1) disabled; linux kernel doesn't contains v4l1
+  hyperbola-meson $pkgname-$pkgver build \
+    -D docs=false \
+    -D graphviz=disabled \
+    -D gexiv2=disabled \
+    -D mrg=disabled \
+    -D lensfun=disabled \
+    -D libv4l=disabled \
+    -D libv4l2=disabled \
+    -D maxflow=disabled \
+    -D umfpack=disabled \
+    -D webp=disabled \
+    -D openexr=disabled \
+    -D workshop=false
+  ninja -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+
+  install -Dm644 $pkgname-$pkgver/COPYING -t $pkgdir/usr/share/licenses/$pkgname
+  install -Dm644 $pkgname-$pkgver/COPYING.LESSER -t $pkgdir/usr/share/licenses/$pkgname
+}