initial import

freeorion/PKGBUILD

@@ -0,0 +1,43 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=freeorion
+pkgver=0.4.10.2
+pkgrel=1
+pkgdesc='A free, turn-based space empire and galactic conquest computer game'
+url='https://www.freeorion.org'
+arch=('i686' 'x86_64')
+license=('GPL-2')
+depends=('boost-libs' 'python' 'tauthon' 'sdl2' 'libvorbis'
+         'glew' 'openal' 'hicolor-icon-theme' 'freetype2')
+makedepends=('boost' 'cmake' 'ninja')
+groups=('games')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/freeorion/freeorion/archive/v${pkgver}.tar.gz"
+        "fix-directories.patch")
+sha512sums=('13832992efe17fe48615ccdf284d1e9f391c35ed518abd15276992128a02894f4b30c8fe3d950e41935efb823cf834dc430330f0bcc6c9e91f13a3dea9812628'
+            '010c5f9019e4c1675bf54d4f7d6492ec3b139ad948bf1957023d215666b56fad39eb8dd158aef3d06c9b08fa92a1620618d994a2e161dc9563cb59f188494bcc')
+
+prepare() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  # fixing data-directories being FHS-compliant
+  patch -Np1 -i "${srcdir}/fix-directories.patch"
+}
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  cmake \
+    -Bbuild \
+    -GNinja \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_BINDIR=games \
+    -DCMAKE_INSTALL_LIBDIR=lib/games \
+    -DCMAKE_INSTALL_DATADIR=share/games
+  ninja -C build
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dm644 README.md -t "${pkgdir}/usr/share/licenses/$pkgname"
+}