initial import

freeciv/PKGBUILD

@@ -0,0 +1,41 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=freeciv
+pkgver=3.0.10
+pkgrel=1
+pkgdesc="A free software, multiuser game about civilizations"
+arch=('i686' 'x86_64')
+url='http://www.freeciv.org/'
+license=('GPL-2')
+depends=('gtk' 'sdl_mixer' 'lua' 'sqlite' 'curl')
+makedepends=('python' 'intltool' 'gettext-tiny')
+groups=('games')
+backup=('etc/freeciv/database.lua')
+source=("https://downloads.sourceforge.net/$pkgname/${pkgname}-${pkgver}.tar.xz")
+sha512sums=('4082e94deeda8d9b90f04137d6e7dfd39ff7232225a910f47519a464db553891e42289c1d7738f9ee0d9a16db143669bf8c4c5ce9492a4455ccd99906c956192')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --bindir=/usr/games \
+    --datarootdir=/usr/share/games \
+    --docdir=/usr/share/doc/$pkgname \
+    --localedir=/usr/share/locale \
+    --mandir=/usr/share/man \
+    --enable-shared \
+    --enable-sys-lua \
+    --enable-client=gtk3 \
+    --enable-fcmp=gtk3 \
+    --enable-fcdb=sqlite3 \
+    --enable-aimodules
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  mv "${pkgdir}"/usr/share/games/icons "${pkgdir}"/usr/share
+  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/$pkgname
+}