initial import

font-manager/PKGBUILD

@@ -0,0 +1,32 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=font-manager
+pkgver=0.8.8
+pkgrel=1
+pkgdesc="A simple, free and libre font management application for GTK+"
+url='https://fontmanager.github.io'
+arch=('i686' 'x86_64')
+license=('GPL-3')
+depends=('gtk' 'json-glib' 'libxml2' 'gettext-tiny' 'sqlite')
+makedepends=('gobject-introspection' 'intltool' 'meson'
+             'ninja' 'vala' 'yelp-tools')
+source=("https://github.com/FontManager/font-manager/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz")
+sha512sums=('75e85af8bbbac4f4f3e73371eb618e75afdd14ea1dc1eab7855db537356c4a9f89121554db2c7a7e2a2357a545a6c2ad69bebbde4ed588a6f9ec0bfe1cc67ad0')
+
+build() {
+  hyperbola-meson "${pkgname}-${pkgver}" build \
+    -Dnautilus=false \
+    -Dwebkit=false \
+    -Dsearch-provider=false \
+    -Dreproducible=true
+  ninja -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+
+  # remove unneeded and unsupported data
+  rm -rf "$pkgdir/usr/share/dbus-1/"
+
+  install -Dm644 "$srcdir/$pkgname-$pkgver/COPYING" -t "$pkgdir/usr/share/licenses/$pkgname"
+}