initial import

desktop-file-utils/PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=desktop-file-utils
+pkgver=0.26
+pkgrel=1
+pkgdesc="Command line utilities for working with desktop entries"
+arch=(i686 x86_64)
+url="https://www.freedesktop.org/wiki/Software/desktop-file-utils"
+license=(GPL-2)
+depends=(glib2)
+source=(https://www.freedesktop.org/software/desktop-file-utils/releases/desktop-file-utils-${pkgver}.tar.xz{,.asc}
+        update-desktop-database.hook)
+sha512sums=('5b4e435f0b635d8f898ac7f5759f74a08ffbe2a56d41fee0e84ff57e73b98d08b57b4416f20b99f696dad8bcb1c20792b39acf836b0814220c0b386ea5f6b831'
+            'SKIP'
+            'a12917f81c13aacd0dd28c4c7db29e85db1fba8b9ef7d80c3b96de4926742f180fcafde353552e35fdfea1dba9fb6ac020305447ed86e0bf51a62efc53812b01')
+validpgpkeys=('C01EDE5BB0D91E26D003662EC76BB9FEEAD12EA7') #Hans Petter Jansson <hpj@suse.com>
+
+prepare() {
+  cd $pkgname-$pkgver
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make check
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 ../*.hook
+  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
+}

desktop-file-utils/update-desktop-database.hook

@@ -0,0 +1,11 @@
+[Trigger]
+Type = File
+Operation = Install
+Operation = Upgrade
+Operation = Remove
+Target = usr/share/applications/*.desktop
+
+[Action]
+Description = Updating the desktop file MIME type cache...
+When = PostTransaction
+Exec = /usr/bin/update-desktop-database --quiet