initial import

deadbeef/PKGBUILD

@@ -0,0 +1,57 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=deadbeef
+pkgver=1.8.7
+pkgrel=2
+pkgdesc="Modular, free and libre GTK+ audio player"
+arch=('i686' 'x86_64')
+url='https://deadbeef.sourceforge.io/'
+license=('GPL-2' 'LGPL-2.1')
+depends=('gtk' 'gtk2' 'alsa-lib' 'jansson')
+makedepends=('libvorbis' 'libmad' 'flac' 'curl' 'imlib2' 'wavpack' 'libsndfile' 'libcdio'
+             'libx11' 'faad2' 'zlib' 'intltool' 'pkgconfig' 'libzip'
+             'libsamplerate' 'yasm' 'ffmpeg' 'clang' 'gettext-tiny')
+optdepends=('cdparanoia: for cd audio plugin'
+            'curl: for artwork plugins'
+            'faad2: for AAC plugin'
+            'ffmpeg: for ffmpeg plugin'
+            'flac: for flac plugin'
+            'imlib2: for artwork plugin'
+            'libcdio: for cd audio plugin'
+            'libice: optional dependency for gtkui session client support'
+            'libmad: for mp3 plugin (mpeg1,2 layers1,2,3)'
+            'libogg: for ogg vorbis plugin'
+            'libsamplerate: for dsp_libsrc plugin (resampler)'
+            'libsidplay: for SID player plugin'
+            'libsm: optional dependency for gtkui session client support'
+            'libsndfile: for sndfile plugin'
+            'libvorbis: for ogg vorbis plugin'
+            'libx11: for global hotkeys plugin'
+            'libzip: for vfs_zip plugin'
+            'mpg123: for MP1/MP2/MP3 playback'
+            'opusfile: for opus plugin'
+            'wavpack: for wavpack plugin'
+            'zlib: for Audio Overload plugin (psf, psf2, etc), GME (for vgz)')
+source=("https://sourceforge.net/projects/deadbeef/files/travis/linux/1.8.7/deadbeef-${pkgver}.tar.bz2"
+        "libre.patch")
+sha512sums=('49a9610f8aa8d9853cd4f9a38d103f9a902993a5ae1990937a3ac5a14a4f8533f4233002893875aedf45f737d1a95c7cea189c61d6387bd8be7f3535d60c96eb'
+            '715b3358c357544c0d792f74f4f6d0ae8ebc0101059cf923cce6539f04ecc19d85f2277d6a2c2f12c6b7365eb571ea17dd3ca19cfbe7e50d53c2d657cdb1e66d')
+
+build () {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  export CC=clang CXX=clang++
+  ./configure \
+    --prefix=/usr
+
+  # removing non-free and not needed parts
+  patch -Np1 -i $srcdir/libre.patch
+
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 COPYING.{GPLv2,LGPLv2.1} -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}