initial import

cogl/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=cogl
+pkgver=1.22.8
+pkgrel=1
+pkgdesc="An object oriented GL/GLES Abstraction/Utility Layer"
+url="https://blogs.gnome.org/clutter/"
+arch=(i686 x86_64)
+license=(Expat SGI-Free-B-2.0 Modified-BSD)
+depends=(mesa-libgl libdrm libxext libxdamage libxcomposite gdk-pixbuf2 pango
+         libxrandr)
+makedepends=(gobject-introspection)
+source=(https://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
+sha512sums=('702d5b1b22dc34bffaa82c9c57021caf036ee3a13fa7ca24a90cca1ebc0f8b7a86070cc1fe5125757132b02774fa874bb55675c96d1ccbc233fac0e6132da65f')
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr \
+    --enable-gles2 \
+    --enable-kms-egl-platform
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
+}
+
+# vim:set ts=2 sw=2 et: