initial import

cmus/PKGBUILD

@@ -0,0 +1,64 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=cmus
+pkgver=2.10.0
+_debver=$pkgver
+_debrel=3
+pkgrel=1
+pkgdesc="Feature-rich ncurses-based music player"
+arch=('i686' 'x86_64')
+url='https://cmus.github.io/'
+license=('GPL-2')
+depends=('ncurses')
+makedepends=('faad2' 'ffmpeg' 'flac' 'jack' 'libao' 'libcdio-paranoia' 'libmad'
+             'libmodplug' 'libmp4v2' 'libmpcdec' 'alsa-lib' 'libsamplerate' 'libsndio'
+             'libvorbis' 'opusfile' 'wavpack' 'quilt')
+optdepends=('alsa-lib: for ALSA output plugin support'
+            'libao: for AO output plugin support'
+            'libsndio: for sndio output plugin support'
+            'faad2: for AAC input plugin support'
+            'ffmpeg: for ffmpeg input plugin support'
+            'flac: for flac input plugin support'
+            'jack: for jack plugin support'
+            'libmad: for mp3 input plugin support'
+            'libmodplug: for modplug input plugin support'
+            'libmp4v2: for mp4 input plugin support'
+            'libmpcdec: for musepack input plugin support'
+            'libsamplerate: for sampe rate converter support'
+            'libvorbis: for vorbis input plugin support'
+            'libcdio-paranoia: for cdio support'
+            'opusfile: for opus input plugin support'
+            'wavpack: for wavpack input plugin support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/cmus/cmus/archive/v${pkgver}.tar.gz"
+        "https://deb.debian.org/debian/pool/main/c/cmus/cmus_$_debver-$_debrel.debian.tar.xz")
+sha512sums=('c055dc974a88f32c7f19fb2e4260ede37fbddc3f23707a98e7f669032c1b4fd9a1032eb5c808cf5ee635617d3abf176e78d1e8596cbe669bbad95cd5c50dde7c'
+            '49325ba2e1384cc612c0caa63766889471396911970f128e674d5d97d635a6d0e4a37247ee5e44415ac153fbd33fcafb26f9462fe960a329e16dd6ca01989d30')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    quilt push -av
+  fi
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure \
+    prefix=/usr
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+  rm "$pkgdir"/usr/share/cmus/{spotify,amazon}.theme
+  install -Dm644 contrib/_cmus "$pkgdir"/usr/share/zsh/site-functions/_cmus
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}