initial import

celestia-legacy/PKGBUILD

@@ -0,0 +1,41 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+_realpkgname=celestia
+pkgname=$_realpkgname-legacy
+pkgver=1.6.2.2
+pkgrel=1
+pkgdesc="Real-time space simulation (legacy version)"
+arch=('i686' 'x86_64')
+license=('GPL-2')
+url='https://celestiaproject.space/'
+depends=('libtheora' 'lua' 'gtkglext' 'freeglut' 'libxmu' 'libjpeg-turbo')
+makedepends=('gettext-tiny')
+options=('!makeflags')
+source=("https://github.com/CelestiaProject/Celestia/archive/$pkgver/$_realpkgname-$pkgver.tar.gz"
+        "fix-desktop.patch")
+sha512sums=('a67cc296a3f176bbe74e9c0bf8d83f6a78cc045edb23fbb870ff42dfd0b53a87af83b57ec35d378338f5dc321ead0d719a350a36036cdc3a2817f9c4b0d89ad2'
+            '13574528ba33f9bb94ed4b505bd5a921ffff92637663dc737f614a0bdce6f6ad1f9d685cf43d20b304b37244d4868909bcad13c82588d071fffd4bc0ff6e5e00')
+
+prepare() {
+  cd Celestia-${pkgver}
+  # fix executable name in desktop file
+  patch -p1 < ${srcdir}/fix-desktop.patch
+  autoreconf -vi
+}
+
+build() {
+  cd Celestia-${pkgver}
+  ./configure --prefix=/usr \
+    --with-lua=/usr \
+    --datadir=/usr/share \
+    --with-gtk \
+    --disable-rpath \
+    --with-lua
+  make
+}
+
+package() {
+  cd Celestia-${pkgver}
+  make DESTDIR="${pkgdir}" MKDIR_P='mkdir -p' install
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}