initial import

calcurse/PKGBUILD

@@ -0,0 +1,37 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=calcurse
+pkgver=4.7.1
+pkgrel=1
+pkgdesc="A text-based, free and libre personal organizer"
+arch=('i686' 'x86_64')
+url='https://calcurse.org/'
+license=('Simplified-BSD')
+depends=('ncurses')
+optdepends=('python: for CalDAV support'
+            'python-httplib2: for CalDAV support'
+            'python-pyparsing: for CalDAV support')
+source=("https://calcurse.org/files/${pkgname}-${pkgver}.tar.gz"{,.asc})
+sha512sums=('8b5574d2909128c745b2d6367b517c5fb04a1c451e666dc9ee0652b3793b519576af5700d4fd073de0ccd5e5dced6b69c45dbfaf98b35a99784093208512b68e'
+            'SKIP')
+validpgpkeys=('2E36D8620221482FC45CB7F2A91764759326B440') # Lukas Fleischer <lfleischer@calcurse.org>
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  ./configure \
+    --enable-docs \
+    --without-asciidoc \
+    --prefix=/usr \
+    --mandir=/usr/share/man
+
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+}