initial import

c-ares/PKGBUILD

@@ -0,0 +1,33 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=c-ares
+pkgver=1.17.1
+pkgrel=1
+pkgdesc='A C library for asynchronous DNS requests'
+arch=('i686' 'x86_64')
+url="https://c-ares.haxx.se/"
+license=('Expat')
+depends=('glibc')
+makedepends=('cmake')
+source=("https://github.com/${pkgname}/${pkgname}/releases/download/${pkgname//-}-${pkgver//./_}/${pkgname}-${pkgver}.tar.gz"{,.asc})
+sha512sums=('b11887bcc9274d368088e1a8b6aca62414f20675cf0bc58e948f54fa04c327c39dd23cefe7509eec6397db14b550a3f6b77f5c18b3d735b3eef48ce2da1dcd00'
+            'SKIP')
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg <daniel@haxx.se>
+
+build() {
+  cd "$pkgname-$pkgver"
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE='None' \
+        -Wno-dev \
+        -B build \
+        -S .
+  make VERBOSE=1 -C build
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make DESTDIR="${pkgdir}" install -C build
+  install -vDm 644 "LICENSE.md" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -vDm 644 {AUTHORS,CHANGES,{CONTRIBUTING,README}.md,RELEASE-NOTES} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/"
+}