initial import

bzr/PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=bzr
+pkgver=2.7.0
+pkgrel=2
+pkgdesc="A decentralized revision control system (bazaar)"
+arch=('i686' 'x86_64')
+url='https://bazaar.canonical.com/'
+license=('GPL-2')
+depends=('tauthon')
+makedepends=('intltool' 'gettext-tiny')
+provides=('bazaar' 'gnu-bazaar' 'breezy' 'brz')
+conflicts=('breezy' 'brz')
+source=("https://launchpad.net/bzr/${pkgver%.*}/${pkgver}/+download/bzr-${pkgver}.tar.gz"{,.sig}
+        "bzr-lazy-regex.patch")
+sha512sums=('c39ad3715d865788da74d8de8b469e1dc93d18b6cbcbc569464cdeb9bb2173bf8d7f4f8ee8f7599fbcbbe322817a4c72e785d544e622753699c425c32597d9aa'
+            'SKIP'
+            '7d873a4e6de19ea8af03c6f8f2371364f76c62ebf787a0c9955beead359ea6591831d387c15867fd6638fee0d306966fdc5c5b2c1a3f0910f03280e6df9802af')
+validpgpkeys=('84736900600FF95EF23513F52975A150DEF6218F') # Vincent Ladeuil
+
+prepare() {
+  cd bzr-${pkgver}
+
+  sed 's|man/man1|share/man/man1|' -i setup.py
+  sed 's|/usr/bin/env python|/usr/bin/env tauthon|' -i bzrlib/{plugins/bash_completion/bashcomp.py,tests/ssl_certs/create_ssls.py,patiencediff.py,_patiencediff_py.py}
+
+  patch -Np0 -i ${srcdir}/bzr-lazy-regex.patch
+}
+
+build() {
+  cd bzr-${pkgver}
+
+  tauthon setup.py build
+}
+
+package() {
+  cd bzr-${pkgver}
+
+  tauthon setup.py install --prefix='/usr' --root="${pkgdir}" --optimize='1'
+
+  install -dm 755 "${pkgdir}"/usr/share/bash-completion/completions
+  install -m 644 contrib/bash/bzr "${pkgdir}"/usr/share/bash-completion/completions/
+
+  install -Dm644 COPYING.txt -t "$pkgdir/usr/share/licenses/$pkgname"
+}