initial import

bzflag/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=bzflag
+pkgver=2.4.26
+pkgrel=1
+pkgdesc="Multiplayer 3D tank battle game"
+url='https://bzflag.org/'
+license=('LGPL-2.1')
+arch=('i686' 'x86_64')
+depends=('curl' 'glew' 'sdl2' 'c-ares')
+makedepends=('intltool' 'gettext-tiny')
+groups=('games')
+source=("https://download.bzflag.org/${pkgname}/source/${pkgver}/${pkgname}-${pkgver}.tar.bz2")
+sha512sums=('1ca039d840440098ea788009ad94fccec20710f621967843b5f95dc4ee054cb1d5d9b94326687008cf7a11020889225ffe9001aac1c7c4339f6761961f422a78')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --bindir=/usr/games \
+    --datarootdir=/usr/share/games
+  make
+  cd misc
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 misc/bzflag.desktop "${pkgdir}"/usr/share/applications/bzflag.desktop
+  install -Dm644 data/bzflag-48x48.png "${pkgdir}"/usr/share/pixmaps/bzflag-48x48.png
+  mv "${pkgdir}"/usr/share/games/man "${pkgdir}"/usr/share/man
+  install -Dm644 COPYING.LGPL -t "${pkgdir}"/usr/share/licenses/$pkgname
+}