initial import

breezy/PKGBUILD

@@ -0,0 +1,62 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=breezy
+pkgver=3.1.0
+_debver=$pkgver
+_debrel=8
+pkgrel=1
+pkgdesc="A decentralized revision control system with support for Bazaar and Git file formats"
+arch=('i686' 'x86_64')
+url='https://www.breezy-vcs.org/'
+license=('GPL-2')
+depends=('python-configobj' 'python-patiencediff' 'python-six')
+makedepends=('python-cython' 'python-dulwich' 'python-fastimport'
+             'python-gpgme' 'python-paramiko' 'python-setuptools'
+             'quilt')
+optdepends=('python-dulwich: Git support'
+            'python-fastimport: Fastimport support'
+            'python-gpgme: PGP support'
+            'python-paramiko: access branches over SFTP')
+provides=('bzr')
+conflicts=('bzr')
+replaces=('bzr')
+source=("https://deb.debian.org/debian/pool/main/b/breezy/breezy_${pkgver}.orig.tar.gz"
+        "https://deb.debian.org/debian/pool/main/b/breezy/breezy_${_debver}-${_debrel}.debian.tar.xz")
+sha512sums=('40ea1ae364940ac8ff83d3f5da2437cc62fbda0ca98b3ae90a38dfad87555c3993b852ce186323454d7ab002ba4fbb3270e70953504e449c445efe147847204d'
+            'd744a6ecb1580ee747771213edb42b5d3ab696e8423701895be306288181545211b13bab5ac6bf66f602efd1ed69068faa830b6f49a50776dbcfbdf9186ff616')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    quilt push -av
+  fi
+}
+
+build() {
+  cd $pkgname-$pkgver
+
+  python setup.py build
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  export PYTHONHASHSEED=0
+  python setup.py install --root="${pkgdir}" --install-data=usr/share --optimize=1 --skip-build
+  ln -s brz "${pkgdir}"/usr/bin/bzr # backwards compatibility
+
+  # fix broken structure
+  mv "${pkgdir}/usr/share/share/locale" "${pkgdir}/usr/share"
+  rm -rf "${pkgdir}/usr/share/share"
+
+  # install license
+  install -Dm644 COPYING.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
+}