initial import

braa/PKGBUILD

@@ -0,0 +1,43 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=braa
+pkgver=0.82
+_debver=$pkgver
+_debrel=6
+pkgrel=1
+pkgdesc="Mass SNMP scanner"
+url='http://s-tech.elsat.net.pl/'
+license=('GPL-2')
+arch=('i686' 'x86_64')
+depends=('glibc')
+makedepends=('quilt')
+source=("https://deb.debian.org/debian/pool/main/b/braa/braa_${pkgver}.orig.tar.gz"
+        "https://deb.debian.org/debian/pool/main/b/braa/braa_$_debver-$_debrel.debian.tar.xz")
+sha512sums=('8c88d288287a12c19c8d49606c8d2b70531b7f2be1aa3c4ccc6b01739aead751c03c56dc3f1a346b3dd20730a8bd0d30e33167a5f7c676f629348195762e23d4'
+            '656622de403cea7962272aa1620246ee7f2442cd38e65eb0f78b7b04a85d2fceb28a82436a000b473b623ee131720ce4678a2c78f063ac418b8aa6e8e638fab7')
+
+prepare() {
+  cd $pkgname-$pkgver
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    quilt push -av
+  fi
+}
+
+build() {
+  cd $pkgname-$pkgver
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  install -Dm755 $pkgname "${pkgdir}/usr/bin/$pkgname"
+  install -Dm644 debian/$pkgname.1 "${pkgdir}/usr/share/man/man1/$pkgname.1"
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}