initial import

autoconf-legacy/PKGBUILD

@@ -0,0 +1,52 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+_pkgname=autoconf
+pkgname=autoconf-legacy
+pkgver=2.13
+_debver=2.13
+_debrel=69
+pkgrel=2
+pkgdesc="A GNU tool for automatically configuring source code (Legacy 2.1x version)"
+arch=(any)
+url="https://www.gnu.org/software/autoconf/autoconf.html"
+license=('GPL-2')
+depends=('perl')
+makedepends=('quilt')
+replaces=('autoconf2.13')
+conflicts=('autoconf2.13')
+provides=('autoconf2.13')
+source=(https://ftp.gnu.org/gnu/autoconf/autoconf-${pkgver}.tar.gz
+        https://deb.debian.org/debian/pool/main/a/autoconf2.13/autoconf2.13_$_debver-$_debrel.debian.tar.xz)
+sha512sums=('602584f4c77b7a554aaa068eda5409b68eb0b3229e9c224bffb91c83c4314d25de15bd560a323626ff78f6df339c79e1ef8938c54b78ecadf4dc75c5241290ad'
+            '1144fdad8df7bcc8854e65362d836ab8e1d07ed01b4ba6af10d295b8b5ba66e55f1f4bafe903be5c965548e1001f0d7f69e5dab00d67897caf2fe482b460c550')
+
+prepare() {
+  cd "${srcdir}/autoconf-${pkgver}"
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    # Doesn't apply and seems unimportant
+    rm -v debian/patches/other-debian.patch || true
+
+    quilt push -av
+  fi
+}
+
+build() {
+  cd "${srcdir}/autoconf-${pkgver}"
+  ./configure --prefix=/usr --infodir=/usr/share/info --program-suffix=-${pkgver}
+  make
+}
+
+package() {
+  cd "${srcdir}/autoconf-${pkgver}"
+  make prefix="${pkgdir}/usr" infodir="${pkgdir}/usr/share/info" install
+  mv "${pkgdir}"/usr/share/info/autoconf{,-${pkgver}}.info
+  mv "${pkgdir}"/usr/share/info/standards{,-${pkgver}}.info
+  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}