initial import

armagetronad/PKGBUILD

@@ -0,0 +1,51 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=armagetronad
+pkgver=0.2.9.2.3
+pkgrel=2
+pkgdesc="A free and libre lightcycle game in 3D"
+arch=('i686' 'x86_64')
+url='https://armagetronad.net/'
+license=('GPL-2')
+depends=('sdl_image' 'libxml2' 'sdl_mixer' 'ftgl' 'hicolor-icon-theme')
+makedepends=('python')
+optdepends=('python: language updater')
+groups=('games')
+source=("https://downloads.sourceforge.net/sourceforge/armagetronad/armagetronad-$pkgver.tbz")
+sha512sums=('813911a75fa1b3a90d99d62c0c38e9b325166623280c0d6a8217f8ca905b4a4617401db12bda898d82aa086a1bd673b31741b95b60b0f1247e6a5677a48c98eb')
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver"
+  2to3 -w language/update.py
+
+  sed -i 's|FTGL.h|ftgl.h|g' configure
+  sed -i 's|png_check_sig|png_sig_cmp|g' configure
+  sed -i -r '/desktop-id/ s/(<!-- )|(org.armagetronad.)|( -->)//g' desktop/armagetronad.appdata.xml.in
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --mandir=/usr/share/man \
+    --enable-automakedefaults \
+    --disable-uninstall
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  # correct package-structure and remove files not needed
+  mv "$pkgdir/usr/bin" "$pkgdir/usr/games"
+  rm -rf "$pkgdir/usr/share/icons"
+  rm -rf "$pkgdir/usr/share/games/$pkgname/desktop"
+  rm -rf "$pkgdir/usr/share/applications"
+
+  # desktop-shortcut, icon and license
+  install -Dm644 "desktop/$pkgname.desktop" -t "$pkgdir/usr/share/applications"
+  install -Dm644 "desktop/icons/32x32/$pkgname.png" "$pkgdir/usr/share/pixmaps/org.armagetronad.armagetronad.png"
+  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+}