initial import

2025-06-22 20:39:04 -05:00
commit f8a70886f0
3428 changed files with 302546 additions and 0 deletions
--- a/7kaa/PKGBUILD
+++ b/7kaa/PKGBUILD
@@ -0,0 +1,70 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=7kaa
+pkgver=2.15.6
+pkgrel=2
+pkgdesc="Seven Kingdoms: Ancient Adversaries is a real-time strategy (RTS) computer game"
+url='http://7kfans.com/'
+arch=('i686' 'x86_64')
+license=('GPL-2' 'CC-BY-4.0' 'CC-BY-3.0' 'CC-BY-SA-4.0')
+depends=('openal' 'desktop-file-utils' 'enet' 'gcc-libs' 'sdl2')
+groups=('games')
+source=("https://sourceforge.net/projects/skfans/files/${pkgname}-${pkgver}.tar.gz"
+        "https://repo.hyperbola.info:50000/sources/${pkgname}/${pkgname}-music.tar.lz"{,.sig}
+        "${pkgname}.sh"
+        "${pkgname}.desktop"
+        "${pkgname}.png"
+        "remove-nonfree-services.patch")
+sha512sums=('8387680b39a203a50bcf466424a4401416d9f60aa00078e4e78a44b89e7afc722a62e81a1f3b5cdb20e323983e4a6506919340261fb6b2829e3ca275e648a64f'
+            'd651ef19d66aec739d4aad504d27f804a44177f958675e4f35f9515d9b27ec7ede40ae5ef0da72518a17c376b0bf78f514c8e5eb05a774eda856fd80bc65bf02'
+            'SKIP'
+            'db0310f69fa44f9e9caba73c1f0825c36902052a36e14945ecf7a112283702e21f6d38480fe1b9fa0355390fa50d6e5d8d7958a6130c1c86dae3357d91fb56ad'
+            '2381d886b5e425ce0a0d11c044c2af582db40fef6ea5fd4b9b811d15bd3544044ded1ce59842d10ed6b85132dcbcc08b8a454799ca86ae04f6999bfe3bd41b99'
+            '7c72537ce58b73880756e45cf9056ce455282a1b34fb0a916994ff1fa8cfbe6e081d8a3f2ef2f772ac16945f15bed6ac04528ae44661c8a1b38b940b08f23c1b'
+            '01ef0d5473280ef4a244fc3da5fda26c30318abcf59a49bc37d335688c43d1fc70e259997de18ce41b539c91e4eb346b58e14f4b7db2a2cb7f6b2387dc71cae2')
+validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva
+
+prepare() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  patch -Np1 -i ${srcdir}/remove-nonfree-services.patch
+}
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  ./configure
+  make
+}
+
+package() {
+  # install data files
+  install -dm755 "${pkgdir}/usr/share/games/${pkgname}/"
+  cd "${srcdir}/$pkgname-$pkgver/data/"
+  cp -r {ENCYC,ENCYC2,IMAGE,RESOURCE,SCENARI2,SCENARIO,SOUND,SPRITE,TUTORIAL} "${pkgdir}/usr/share/games/${pkgname}/"
+
+  # install music
+  cd "${srcdir}/$pkgname-music/"
+  cp -r MUSIC "${pkgdir}/usr/share/games/${pkgname}/"
+
+  # fix permissions
+  cd "${pkgdir}/usr/share/games/${pkgname}/"
+  find . -type d -exec chmod 755 {} \;
+  find . -type f -exec chmod 755 {} \;
+
+  # copy readme
+  install -D -m644 "${srcdir}/$pkgname-$pkgver/README" "${pkgdir}/usr/share/doc/${pkgname}/README"
+
+  # main file
+  install -dm755 "${pkgdir}/usr/share/games/${pkgname}/"
+  install -D -m755 "${srcdir}/${pkgname}-${pkgver}/src/${pkgname}" "${pkgdir}/usr/share/games/${pkgname}/${pkgname}"
+
+  # bash script
+  install -D -m755 "$srcdir/${pkgname}.sh" "${pkgdir}/usr/games/${pkgname}"
+
+  # desktop entry
+  install -D -m644 "$srcdir/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  install -D -m644 "${srcdir}/${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
+
+  # licenses
+  install -Dm644 "${srcdir}/$pkgname-$pkgver/COPYING" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm644 "${srcdir}/${pkgname}-music/COPYING-Music.txt" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}